现在的位置: 首页 ＞BashShell＞正文
小 中 大
sed单行脚本快速参考
发表于10年前 ⁄ BashShell ⁄ 暂无评论 ⁄ 被围观 4,735 次+
 
  1. -------------------------------------------------------------------------   
  2. SED单行脚本快速参考（Unix 流编辑器）                       2005年12月29日   
  3.   
  4. 英文标题：USEFUL ONE-LINE SCRIPTS FOR SED (Unix stream editor)   
  5. 原标题：HANDY ONE-LINERS FOR SED (Unix stream editor)   
  6.   
  7. 整理：Eric Pement  - 电邮：pemente[at]northpark[dot]edu         版本5.5   
  8. 译者：Joe Hong     - 电邮：hq00e[at]126[dot]com   
  9.   
  10. 在以下地址可找到本文档的最新（英文）版本：   
  11.    http://sed.sourceforge.net/sed1line.txt   
  12.    http://www.pement.org/sed/sed1line.txt   
  13.   
  14. 其他语言版本：   
  15.   中文          - http://sed.sourceforge.net/sed1line_zh-CN.html   
  16.   捷克语        - http://sed.sourceforge.net/sed1line_cz.html   
  17.   荷语          - http://sed.sourceforge.net/sed1line_nl.html   
  18.   法语          - http://sed.sourceforge.net/sed1line_fr.html   
  19.   德语          - http://sed.sourceforge.net/sed1line_de.html   
  20.   
  21.   葡语          - http://sed.sourceforge.net/sed1line_pt-BR.html   
  22.   
  23.   
  24. 文本间隔：   
  25. --------   
  26.   
  27.  # 在每一行后面增加一空行   
  28.  sed G   
  29.   
  30.  # 将原来的所有空行删除并在每一行后面增加一空行。   
  31.  # 这样在输出的文本中每一行后面将有且只有一空行。   
  32.  sed '/^$/d;G'   
  33.   
  34.  # 在每一行后面增加两行空行   
  35.  sed 'G;G'   
  36.   
  37.  # 将第一个脚本所产生的所有空行删除（即删除所有偶数行）   
  38.  sed 'n;d'   
  39.   
  40.  # 在匹配式样“regex”的行之前插入一空行   
  41.  sed '/regex/{x;p;x;}'   
  42.   
  43.  # 在匹配式样“regex”的行之后插入一空行   
  44.  sed '/regex/G'   
  45.   
  46.  # 在匹配式样“regex”的行之前和之后各插入一空行   
  47.  sed '/regex/{x;p;x;G;}'   
  48.   
  49. 编号：   
  50. --------   
  51.   
  52.  # 为文件中的每一行进行编号（简单的左对齐方式）。这里使用了“制表符”   
  53.  # （tab，见本文末尾关于'\t'的用法的描述）而不是空格来对齐边缘。   
  54.  sed = filename | sed 'N;s/\n/\t/'   
  55.   
  56.  # 对文件中的所有行编号（行号在左，文字右端对齐）。   
  57.  sed = filename | sed 'N; s/^/     /; s/ *\(.\{6,\}\)\n/\1  /'   
  58.   
  59.  # 对文件中的所有行编号，但只显示非空白行的行号。   
  60.  sed '/./=' filename | sed '/./N; s/\n/ /'   
  61.   
  62.  # 计算行数 （模拟 "wc -l"）   
  63.  sed -n '$='   
  64.   
  65. 文本转换和替代：   
  66. --------   
  67.   
  68.  # Unix环境：转换DOS的新行符（CR/LF）为Unix格式。   
  69.  sed 's/.$//'                     # 假设所有行以CR/LF结束   
  70.  sed 's/^M$//'                    # 在bash/tcsh中，将按Ctrl-M改为按Ctrl-V   
  71.  sed 's/\x0D$//'                  # ssed、gsed 3.02.80，及更高版本   
  72.   
  73.  # Unix环境：转换Unix的新行符（LF）为DOS格式。   
  74.  sed "s/$/`echo -e \\\r`/"        # 在ksh下所使用的命令   
  75.  sed 's/$'"/`echo \\\r`/"         # 在bash下所使用的命令   
  76.  sed "s/$/`echo \\\r`/"           # 在zsh下所使用的命令   
  77.  sed 's/$/\r/'                    # gsed 3.02.80 及更高版本   
  78.   
  79.  # DOS环境：转换Unix新行符（LF）为DOS格式。   
  80.  sed "s/$//"                      # 方法 1   
  81.  sed -n p                         # 方法 2   
  82.   
  83.  # DOS环境：转换DOS新行符（CR/LF）为Unix格式。   
  84.  # 下面的脚本只对UnxUtils sed 4.0.7 及更高版本有效。要识别UnxUtils版本的   
  85.  #  sed可以通过其特有的“--text”选项。你可以使用帮助选项（“--help”）看   
  86.  # 其中有无一个“--text”项以此来判断所使用的是否是UnxUtils版本。其它DOS   
  87.  # 版本的的sed则无法进行这一转换。但可以用“tr”来实现这一转换。   
  88.  sed "s/\r//" infile >outfile     # UnxUtils sed v4.0.7 或更高版本   
  89.  tr -d \r <infile >outfile        # GNU tr 1.22 或更高版本   
  90.   
  91.  # 将每一行前导的“空白字符”（空格，制表符）删除   
  92.  # 使之左对齐   
  93.  sed 's/^[ \t]*//'                # 见本文末尾关于'\t'用法的描述   
  94.   
  95.  # 将每一行拖尾的“空白字符”（空格，制表符）删除   
  96.  sed 's/[ \t]*$//'                # 见本文末尾关于'\t'用法的描述   
  97.   
  98.  # 将每一行中的前导和拖尾的空白字符删除   
  99.  sed 's/^[ \t]*//;s/[ \t]*$//'   
  100.   
  101.  # 在每一行开头处插入5个空格（使全文向右移动5个字符的位置）   
  102.  sed 's/^/     /'   
  103.   
  104.  # 以79个字符为宽度，将所有文本右对齐   
  105.  sed -e :a -e 's/^.\{1,78\}$/ &/;ta'  # 78个字符外加最后的一个空格   
  106.   
  107.  # 以79个字符为宽度，使所有文本居中。在方法1中，为了让文本居中每一行的前   
  108.  # 头和后头都填充了空格。 在方法2中，在居中文本的过程中只在文本的前面填充   
  109.  # 空格，并且最终这些空格将有一半会被删除。此外每一行的后头并未填充空格。   
  110.  sed  -e :a -e 's/^.\{1,77\}$/ & /;ta'                     # 方法1   
  111.  sed  -e :a -e 's/^.\{1,77\}$/ &/;ta' -e 's/\( *\)\1/\1/'  # 方法2   
  112.   
  113.  # 在每一行中查找字串“foo”，并将找到的“foo”替换为“bar”   
  114.  sed 's/foo/bar/'                 # 只替换每一行中的第一个“foo”字串   
  115.  sed 's/foo/bar/4'                # 只替换每一行中的第四个“foo”字串   
  116.  sed 's/foo/bar/g'                # 将每一行中的所有“foo”都换成“bar”   
  117.  sed 's/\(.*\)foo\(.*foo\)/\1bar\2/' # 替换倒数第二个“foo”   
  118.  sed 's/\(.*\)foo/\1bar/'            # 替换最后一个“foo”   
  119.   
  120.  # 只在行中出现字串“baz”的情况下将“foo”替换成“bar”   
  121.  sed '/baz/s/foo/bar/g'   
  122.   
  123.  # 将“foo”替换成“bar”，并且只在行中未出现字串“baz”的情况下替换   
  124.  sed '/baz/!s/foo/bar/g'   
  125.   
  126.  # 不管是“scarlet”“ruby”还是“puce”，一律换成“red”   
  127.  sed 's/scarlet/red/g;s/ruby/red/g;s/puce/red/g'  #对多数的sed都有效   
  128.  gsed 's/scarlet\|ruby\|puce/red/g'               # 只对GNU sed有效   
  129.   
  130.  # 倒置所有行，第一行成为最后一行，依次类推（模拟“tac”）。   
  131.  # 由于某些原因，使用下面命令时HHsed v1.5会将文件中的空行删除   
  132.  sed '1!G;h;$!d'               # 方法1   
  133.  sed -n '1!G;h;$p'             # 方法2   
  134.   
  135.  # 将行中的字符逆序排列，第一个字成为最后一字，……（模拟“rev”）   
  136.  sed '/\n/!G;s/\(.\)\(.*\n\)/&\2\1/;//D;s/.//'   
  137.   
  138.  # 将每两行连接成一行（类似“paste”）   
  139.  sed '$!N;s/\n/ /'   
  140.   
  141.  # 如果当前行以反斜杠“\”结束，则将下一行并到当前行末尾   
  142.  # 并去掉原来行尾的反斜杠   
  143.  sed -e :a -e '/\\$/N; s/\\\n//; ta'   
  144.   
  145.  # 如果当前行以等号开头，将当前行并到上一行末尾   
  146.  # 并以单个空格代替原来行头的“=”   
  147.  sed -e :a -e '$!N;s/\n=/ /;ta' -e 'P;D'   
  148.   
  149.  # 为数字字串增加逗号分隔符号，将“1234567”改为“1,234,567”   
  150.  gsed ':a;s/\B[0-9]\{3\}\>/,&/;ta'                     # GNU sed   
  151.  sed -e :a -e 's/\(.*[0-9]\)\([0-9]\{3\}\)/\1,\2/;ta'  # 其他sed   
  152.   
  153.  # 为带有小数点和负号的数值增加逗号分隔符（GNU sed）   
  154.  gsed -r ':a;s/(^|[^0-9.])([0-9]+)([0-9]{3})/\1\2,\3/g;ta'   
  155.   
  156.  # 在每5行后增加一空白行 （在第5，10，15，20，等行后增加一空白行）   
  157.  gsed '0~5G'                      # 只对GNU sed有效   
  158.  sed 'n;n;n;n;G;'                 # 其他sed   
  159.   
  160. 选择性地显示特定行：   
  161. --------   
  162.   
  163.  # 显示文件中的前10行 （模拟“head”的行为）   
  164.  sed 10q   
  165.   
  166.  # 显示文件中的第一行 （模拟“head -1”命令）   
  167.  sed q  
  168.   
  169.  # 显示文件中的最后10行 （模拟“tail”）   
  170.  sed -e :a -e '$q;N;11,$D;ba'   
  171.   
  172.  # 显示文件中的最后2行（模拟“tail -2”命令）   
  173.  sed '$!N;$!D'   
  174.   
  175.  # 显示文件中的最后一行（模拟“tail -1”）   
  176.  sed '$!d'                        # 方法1   
  177.  sed -n '$p'                      # 方法2   
  178.   
  179.  # 显示文件中的倒数第二行   
  180.  sed -e '$!{h;d;}' -e x              # 当文件中只有一行时，输入空行   
  181.  sed -e '1{$q;}' -e '$!{h;d;}' -e x  # 当文件中只有一行时，显示该行   
  182.  sed -e '1{$d;}' -e '$!{h;d;}' -e x  # 当文件中只有一行时，不输出   
  183.   
  184.  # 只显示匹配正则表达式的行（模拟“grep”）   
  185.  sed -n '/regexp/p'               # 方法1   
  186.  sed '/regexp/!d'                 # 方法2   
  187.   
  188.  # 只显示“不”匹配正则表达式的行（模拟“grep -v”）   
  189.  sed -n '/regexp/!p'              # 方法1，与前面的命令相对应   
  190.  sed '/regexp/d'                  # 方法2，类似的语法   
  191.   
  192.  # 查找“regexp”并将匹配行的上一行显示出来，但并不显示匹配行   
  193.  sed -n '/regexp/{g;1!p;};h'   
  194.   
  195.  # 查找“regexp”并将匹配行的下一行显示出来，但并不显示匹配行   
  196.  sed -n '/regexp/{n;p;}'   
  197.   
  198.  # 显示包含“regexp”的行及其前后行，并在第一行之前加上“regexp”所   
  199.  # 在行的行号 （类似“grep -A1 -B1”）   
  200.  sed -n -e '/regexp/{=;x;1!p;g;$!N;p;D;}' -e h   
  201.   
  202.  # 显示包含“AAA”、“BBB”或“CCC”的行（任意次序）   
  203.  sed '/AAA/!d; /BBB/!d; /CCC/!d'  # 字串的次序不影响结果   
  204.   
  205.  # 显示包含“AAA”、“BBB”和“CCC”的行（固定次序）   
  206.  sed '/AAA.*BBB.*CCC/!d'   
  207.   
  208.  # 显示包含“AAA”“BBB”或“CCC”的行 （模拟“egrep”）   
  209.  sed -e '/AAA/b' -e '/BBB/b' -e '/CCC/b' -e d    # 多数sed   
  210.  gsed '/AAA\|BBB\|CCC/!d'                        # 对GNU sed有效   
  211.   
  212.  # 显示包含“AAA”的段落 （段落间以空行分隔）   
  213.  # HHsed v1.5 必须在“x;”后加入“G;”，接下来的3个脚本都是这样   
  214.  sed -e '/./{H;$!d;}' -e 'x;/AAA/!d;'   
  215.   
  216.  # 显示包含“AAA”“BBB”和“CCC”三个字串的段落 （任意次序）   
  217.  sed -e '/./{H;$!d;}' -e 'x;/AAA/!d;/BBB/!d;/CCC/!d'   
  218.   
  219.  # 显示包含“AAA”、“BBB”、“CCC”三者中任一字串的段落 （任意次序）   
  220.  sed -e '/./{H;$!d;}' -e 'x;/AAA/b' -e '/BBB/b' -e '/CCC/b' -e d   
  221.  gsed '/./{H;$!d;};x;/AAA\|BBB\|CCC/b;d'         # 只对GNU sed有效   
  222.   
  223.  # 显示包含65个或以上字符的行   
  224.  sed -n '/^.\{65\}/p'   
  225.   
  226.  # 显示包含65个以下字符的行   
  227.  sed -n '/^.\{65\}/!p'            # 方法1，与上面的脚本相对应   
  228.  sed '/^.\{65\}/d'                # 方法2，更简便一点的方法   
  229.   
  230.  # 显示部分文本——从包含正则表达式的行开始到最后一行结束   
  231.  sed -n '/regexp/,$p'   
  232.   
  233.  # 显示部分文本——指定行号范围（从第8至第12行，含8和12行）   
  234.  sed -n '8,12p'                   # 方法1   
  235.  sed '8,12!d'                     # 方法2   
  236.   
  237.  # 显示第52行   
  238.  sed -n '52p'                     # 方法1   
  239.  sed '52!d'                       # 方法2   
  240.  sed '52q;d'                      # 方法3, 处理大文件时更有效率   
  241.   
  242.  # 从第3行开始，每7行显示一次       
  243.  gsed -n '3~7p'                   # 只对GNU sed有效   
  244.  sed -n '3,${p;n;n;n;n;n;n;}'     # 其他sed   
  245.   
  246.  # 显示两个正则表达式之间的文本（包含）   
  247.  sed -n '/Iowa/,/Montana/p'       # 区分大小写方式   
  248.   
  249. 选择性地删除特定行：   
  250. --------   
  251.   
  252.  # 显示通篇文档，除了两个正则表达式之间的内容   
  253.  sed '/Iowa/,/Montana/d'   
  254.   
  255.  # 删除文件中相邻的重复行（模拟“uniq”）   
  256.  # 只保留重复行中的第一行，其他行删除   
  257.  sed '$!N; /^\(.*\)\n\1$/!P; D'   
  258.   
  259.  # 删除文件中的重复行，不管有无相邻。注意hold space所能支持的缓存   
  260.  # 大小，或者使用GNU sed。   
  261.  sed -n 'G; s/\n/&&/; /^\([ -~]*\n\).*\n\1/d; s/\n//; h; P'   
  262.   
  263.  # 删除除重复行外的所有行（模拟“uniq -d”）   
  264.  sed '$!N; s/^\(.*\)\n\1$/\1/; t; D'   
  265.   
  266.  # 删除文件中开头的10行   
  267.  sed '1,10d'   
  268.   
  269.  # 删除文件中的最后一行   
  270.  sed '$d'   
  271.   
  272.  # 删除文件中的最后两行   
  273.  sed 'N;$!P;$!D;$d'   
  274.   
  275.  # 删除文件中的最后10行   
  276.  sed -e :a -e '$d;N;2,10ba' -e 'P;D'   # 方法1   
  277.  sed -n -e :a -e '1,10!{P;N;D;};N;ba'  # 方法2   
  278.   
  279.  # 删除8的倍数行   
  280.  gsed '0~8d'                           # 只对GNU sed有效   
  281.  sed 'n;n;n;n;n;n;n;d;'                # 其他sed   
  282.   
  283.  # 删除匹配式样的行   
  284.  sed '/pattern/d'                      # 删除含pattern的行。当然pattern   
  285.                                        # 可以换成任何有效的正则表达式   
  286.   
  287.  # 删除文件中的所有空行（与“grep '.' ”效果相同）   
  288.  sed '/^$/d'                           # 方法1   
  289.  sed '/./!d'                           # 方法2   
  290.   
  291.  # 只保留多个相邻空行的第一行。并且删除文件顶部和尾部的空行。   
  292.  # （模拟“cat -s”）   
  293.  sed '/./,/^$/!d'        #方法1，删除文件顶部的空行，允许尾部保留一空行   
  294.  sed '/^$/N;/\n$/D'      #方法2，允许顶部保留一空行，尾部不留空行   
  295.   
  296.  # 只保留多个相邻空行的前两行。   
  297.  sed '/^$/N;/\n$/N;//D'   
  298.   
  299.  # 删除文件顶部的所有空行   
  300.  sed '/./,$!d'   
  301.   
  302.  # 删除文件尾部的所有空行   
  303.  sed -e :a -e '/^\n*$/{$d;N;ba' -e '}'  # 对所有sed有效   
  304.  sed -e :a -e '/^\n*$/N;/\n$/ba'        # 同上，但只对 gsed 3.02.*有效   
  305.   
  306.  # 删除每个段落的最后一行   
  307.  sed -n '/^$/{p;h;};/./{x;/./p;}'   
  308.   
  309. 特殊应用：   
  310. --------   
  311.   
  312.  # 移除手册页（man page）中的nroff标记。在Unix System V或bash shell下使   
  313.  # 用'echo'命令时可能需要加上 -e 选项。   
  314.  sed "s/.`echo \\\b`//g"    # 外层的双括号是必须的（Unix环境）   
  315.  sed 's/.^H//g'             # 在bash或tcsh中, 按 Ctrl-V 再按 Ctrl-H   
  316.  sed 's/.\x08//g'           # sed 1.5，GNU sed，ssed所使用的十六进制的表示方法   
  317.   
  318.  # 提取新闻组或 e-mail 的邮件头   
  319.  sed '/^$/q'                # 删除第一行空行后的所有内容   
  320.   
  321.  # 提取新闻组或 e-mail 的正文部分   
  322.  sed '1,/^$/d'              # 删除第一行空行之前的所有内容   
  323.   
  324.  # 从邮件头提取“Subject”（标题栏字段），并移除开头的“Subject:”字样   
  325.  sed '/^Subject: */!d; s///;q'   
  326.   
  327.  # 从邮件头获得回复地址   
  328.  sed '/^Reply-To:/q; /^From:/h; /./d;g;q'   
  329.   
  330.  # 获取邮件地址。在上一个脚本所产生的那一行邮件头的基础上进一步的将非电邮   
  331.  # 地址的部分剃除。（见上一脚本）   
  332.  sed 's/ *(.*)//; s/>.*//; s/.*[:<] *//'   
  333.   
  334.  # 在每一行开头加上一个尖括号和空格（引用信息）   
  335.  sed 's/^/> /'   
  336.   
  337.  # 将每一行开头处的尖括号和空格删除（解除引用）   
  338.  sed 's/^> //'   
  339.   
  340.  # 移除大部分的HTML标签（包括跨行标签）   
  341.  sed -e :a -e 's/<[^>]*>//g;/</N;//ba'   
  342.   
  343.  # 将分成多卷的uuencode文件解码。移除文件头信息，只保留uuencode编码部分。   
  344.  # 文件必须以特定顺序传给sed。下面第一种版本的脚本可以直接在命令行下输入；   
  345.  # 第二种版本则可以放入一个带执行权限的shell脚本中。（由Rahul Dhesi的一   
  346.  # 个脚本修改而来。）   
  347.  sed '/^end/,/^begin/d' file1 file2 ... fileX | uudecode   # vers. 1   
  348.  sed '/^end/,/^begin/d' "$@" | uudecode                    # vers. 2   
  349.   
  350.  # 将文件中的段落以字母顺序排序。段落间以（一行或多行）空行分隔。GNU sed使用   
  351.  # 字元“\v”来表示垂直制表符，这里用它来作为换行符的占位符——当然你也可以   
  352.  # 用其他未在文件中使用的字符来代替它。   
  353.  sed '/./{H;d;};x;s/\n/={NL}=/g' file | sort | sed '1s/={NL}=//;s/={NL}=/\n/g'   
  354.  gsed '/./{H;d};x;y/\n/\v/' file | sort | sed '1s/\v//;y/\v/\n/'   
  355.   
  356.  # 分别压缩每个.TXT文件，压缩后删除原来的文件并将压缩后的.ZIP文件   
  357.  # 命名为与原来相同的名字（只是扩展名不同）。（DOS环境：“dir /b”   
  358.  # 显示不带路径的文件名）。   
  359.  echo @echo off >zipup.bat   
  360.  dir /b *.txt | sed "s/^\(.*\)\.TXT/pkzip -mo \1 \1.TXT/" >>zipup.bat   
  361.   
  362.   
  363. 使用SED：Sed接受一个或多个编辑命令，并且每读入一行后就依次应用这些命令。   
  364. 当读入第一行输入后，sed对其应用所有的命令，然后将结果输出。接着再读入第二   
  365. 行输入，对其应用所有的命令……并重复这个过程。上一个例子中sed由标准输入设   
  366. 备（即命令解释器，通常是以管道输入的形式）获得输入。在命令行给出一个或多   
  367. 个文件名作为参数时，这些文件取代标准输入设备成为sed的输入。sed的输出将被   
  368. 送到标准输出（显示器）。因此：   
  369.   
  370.  cat filename | sed '10q'         # 使用管道输入   
  371.  sed '10q' filename               # 同样效果，但不使用管道输入   
  372.  sed '10q' filename > newfile     # 将输出转移（重定向）到磁盘上   
  373.   
  374. 要了解sed命令的使用说明，包括如何通过脚本文件（而非从命令行）来使用这些命   
  375. 令，请参阅《sed & awk》第二版，作者Dale Dougherty和Arnold Robbins   
  376. （O'Reilly，1997；http://www.ora.com），《UNIX Text Processing》，作者   
  377. Dale Dougherty和Tim O'Reilly（Hayden Books，1987）或者是Mike Arst写的教   
  378. 程——压缩包的名称是“U-SEDIT2.ZIP”（在许多站点上都找得到）。要发掘sed   
  379. 的潜力，则必须对“正则表达式”有足够的理解。正则表达式的资料可以看   
  380. 《Mastering Regular Expressions》作者Jeffrey Friedl（O'reilly 1997）。   
  381. Unix系统所提供的手册页（“man”）也会有所帮助（试一下这些命令   
  382. “man sed”、“man regexp”，或者看“man ed”中关于正则表达式的部分），但   
  383. 手册提供的信息比较“抽象”——这也是它一直为人所诟病的。不过，它本来就不   
  384. 是用来教初学者如何使用sed或正则表达式的教材，而只是为那些熟悉这些工具的人   
  385. 提供的一些文本参考。   
  386.   
  387. 括号语法：前面的例子对sed命令基本上都使用单引号（'...'）而非双引号   
  388. （"..."）这是因为sed通常是在Unix平台上使用。单引号下，Unix的shell（命令   
  389. 解释器）不会对美元符（$）和后引号（`...`）进行解释和执行。而在双引号下   
  390. 美元符会被展开为变量或参数的值，后引号中的命令被执行并以输出的结果代替   
  391. 后引号中的内容。而在“csh”及其衍生的shell中使用感叹号（!）时需要在其前   
  392. 面加上转义用的反斜杠（就像这样：\!）以保证上面所使用的例子能正常运行   
  393. （包括使用单引号的情况下）。DOS版本的Sed则一律使用双引号（"..."）而不是   
  394. 引号来圈起命令。   
  395.   
  396. '\t'的用法：为了使本文保持行文简洁，我们在脚本中使用'\t'来表示一个制表   
  397. 符。但是现在大部分版本的sed还不能识别'\t'的简写方式，因此当在命令行中为   
  398. 脚本输入制表符时，你应该直接按TAB键来输入制表符而不是输入'\t'。下列的工   
  399. 具软件都支持'\t'做为一个正则表达式的字元来表示制表符：awk、perl、HHsed、   
  400. sedmod以及GNU sed v3.02.80。   
  401.   
  402. 不同版本的SED：不同的版本间的sed会有些不同之处，可以想象它们之间在语法上   
  403. 会有差异。具体而言，它们中大部分不支持在编辑命令中间使用标签（:name）或分   
  404. 支命令（b,t），除非是放在那些的末尾。这篇文档中我们尽量选用了可移植性较高   
  405. 的语法，以使大多数版本的sed的用户都能使用这些脚本。不过GNU版本的sed允许使   
  406. 用更简洁的语法。想像一下当读者看到一个很长的命令时的心情：   
  407.   
  408.    sed -e '/AAA/b' -e '/BBB/b' -e '/CCC/b' -e d   
  409.   
  410. 好消息是GNU sed能让命令更紧凑：   
  411.   
  412.    sed '/AAA/b;/BBB/b;/CCC/b;d'      # 甚至可以写成   
  413.    sed '/AAA\|BBB\|CCC/b;d'   
  414.   
  415. 此外，请注意虽然许多版本的sed接受象“/one/ s/RE1/RE2/”这种在's'前带有空   
  416. 格的命令，但这些版本中有些却不接受这样的命令:“/one/! s/RE1/RE2/”。这时   
  417. 只需要把中间的空格去掉就行了。   
  418.   
  419. 速度优化：当由于某种原因（比如输入文件较大、处理器或硬盘较慢等）需要提高   
  420. 命令执行速度时，可以考虑在替换命令（“s/.../.../”）前面加上地址表达式来   
  421. 提高速度。举例来说：   
  422.   
  423.    sed 's/foo/bar/g' filename         # 标准替换命令   
  424.    sed '/foo/ s/foo/bar/g' filename   # 速度更快   
  425.    sed '/foo/ s//bar/g' filename      # 简写形式   
  426.   
  427. 当只需要显示文件的前面的部分或需要删除后面的内容时，可以在脚本中使用“q”   
  428. 命令（退出命令）。在处理大的文件时，这会节省大量时间。因此：   
  429.   
  430.    sed -n '45,50p' filename           # 显示第45到50行   
  431.    sed -n '51q;45,50p' filename       # 一样，但快得多   
  432.   
  433. 如果你有其他的单行脚本想与大家分享或者你发现了本文档中错误的地方，请发电   
  434. 子邮件给本文档的作者（Eric Pement）。邮件中请记得提供你所使用的sed版本、    
  435. 该sed所运行的操作系统及对问题的适当描述。本文所指的单行脚本指命令行的长   
  436. 度在65个字符或65个以下的sed脚本〔译注1〕。本文档的各种脚本是由以下所列作   
  437. 者所写或提供：   
  438.   
  439.  Al Aab                               # 建立了“seders”邮件列表   
  440.  Edgar Allen                          # 许多方面   
  441.  Yiorgos Adamopoulos                  # 许多方面   
  442.  Dale Dougherty                       # 《sed & awk》作者   
  443.  Carlos Duarte                        # 《do it with sed》作者   
  444.  Eric Pement                          # 本文档的作者   
  445.  Ken Pizzini                          # GNU sed v3.02 的作者   
  446.  S.G. Ravenhall                       # 去html标签脚本   
  447.  Greg Ubben                           # 有诸多贡献并提供了许多帮助   
  448. -------------------------------------------------------------------------   
  449.   
  450. 译注1：大部分情况下，sed脚本无论多长都能写成单行的形式（通过`-e'选项和`;'   
  451. 号）——只要命令解释器支持，所以这里说的单行脚本除了能写成一行还对长度有   
  452. 所限制。因为这些单行脚本的意义不在于它们是以单行的形式出现。而是让用户能   
  453. 方便地在命令行中使用这些紧凑的脚本才是其意义所在。   
返回

作者:

该日志由 夜舞 于2011年06月23日发表在BashShell分类下， 你可以发表评论，并在保留原文地址及作者的情况下引用到你的网站或博客。
转载请注明: sed单行脚本快速参考 | 夜舞倾城 +复制链接
关键字: , ,
【上篇】
【下篇】

您可能还会对这些文章感兴趣！

  1. shell脚本binary operator expected错误
  2. shell获取外网ip
  3. 24 个很酷的 Linux/Unix 工具
  4. Linux给力的Shell命令(1)
  5. Grep学习笔记
  6. Awk1line中文版
  7. 使用SendEmail在命令行发送邮件
  8. linux连接多个远程桌面
windows局域网同步时间

给我留言

留言无头像?


插入图片

返回首页

Copyright © 2011-2012 夜舞倾城  保留所有权利.   基于 WordPress 技术创建   Theme by Robin